cronos/flake.nix at main · tsinglua/cronos · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/release-25.11";
    flake-utils.url = "github:numtide/flake-utils";
    nix-bundle-exe = {
      url = "github:3noch/nix-bundle-exe";
      flake = false;
    };
    gomod2nix = {
      url = "github:nix-community/gomod2nix";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-utils.follows = "flake-utils";
    };
    poetry2nix = {
      url = "github:nix-community/poetry2nix";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-utils.follows = "flake-utils";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      nix-bundle-exe,
      gomod2nix,
      flake-utils,
      poetry2nix,
    }:
    let
      rev = self.shortRev or "dirty";
      gomodOverlay =
        final: prev:
        let
          gomodSrc = gomod2nix.outPath;
          callPackage = final.callPackage;
        in
        {
          inherit (callPackage "${gomodSrc}/builder" { }) buildGoApplication mkGoEnv mkVendorEnv;
          gomod2nix = (callPackage "${gomodSrc}/default.nix" { }).overrideAttrs (_: {
            modRoot = ".";
          });
        };
      mkApp = drv: {
        type = "app";
        program = "${drv}/bin/${drv.meta.mainProgram}";
      };
    in
    (flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = self.overlays.default;
          config = { };
        };
      in
      rec {
        packages = pkgs.cronos-matrix // {
          inherit (pkgs) rocksdb testground-image;
        };
        apps = {
          cronosd = mkApp packages.cronosd;
          cronosd-testnet = mkApp packages.cronosd-testnet;
          stateless-testcase = {
            type = "app";
            program = "${pkgs.benchmark-testcase}/bin/stateless-testcase";
          };
        };
        defaultPackage = packages.cronosd;
        defaultApp = apps.cronosd;
        devShells = rec {
          default = pkgs.mkShell {
            buildInputs = [
              defaultPackage.go
              pkgs.gomod2nix
              pkgs.nixfmt-rfc-style
            ];
          };
          rocksdb = pkgs.mkShell {
            buildInputs = default.buildInputs ++ [
              pkgs.rocksdb
              pkgs.rocksdb.tools
            ];
          };
          full = pkgs.mkShell { buildInputs = rocksdb.buildInputs ++ [ pkgs.test-env ]; };
        };
        legacyPackages = pkgs;
      }
    ))
    // {
      overlays.default = [
        (import ./nix/build_overlay.nix)
        poetry2nix.overlays.default
        gomodOverlay
        (import ./testground/benchmark/overlay.nix)
        (final: super: {
          go = final.go_1_25;
          test-env = final.callPackage ./nix/testenv.nix { pkgs = final; };
          cronos-matrix = final.callPackage ./nix/cronos-matrix.nix {
            inherit rev;
            bundle-exe = final.pkgsBuildBuild.callPackage nix-bundle-exe { };
          };
          testground-image = final.callPackage ./nix/testground-image.nix { };
        })
      ];
    };
}